20.3 Способы работы с файлами и временным хранилищем

Печать (Ctrl+P)
В данном разделе описаны наиболее частые варианты использования механизма работы с временным хранилищем и файлами.

Сохранение данных из файла во временное хранилище

 Помещение одного файла

Метод ПоместитьФайл() помещает файл из локальной файловой системы во временное хранилище. Метод может принимать адрес во временном хранилище, по которому нужно сохранить файл. Если же адрес не определен или является пустой строкой, то будет создан новый адрес и метод вернет его через специальный параметр.
Примечание. Объем данных, перемещаемых между клиентом и сервером, за один вызов метода ПоместитьФайл(), не должен превышать 4 Gb (в сериализованном виде).
Если параметр, определяющий интерактивный режим работы, равен Истина, то метод отобразит стандартное диалоговое окно выбора файла, в котором можно выбрать файл для помещения в хранилище. В этом случае метод также вернет адрес выбранного файла.
В качестве результата метод возвращает Ложь, если пользователь в интерактивном режиме отказался от совершения операции в диалоге выбора файла.

Помещение набора файлов

Метод ПоместитьФайлы() помещает во временное хранилище несколько файлов за один вызов. Существует несколько различных способов использования этого метода:
● предварительно сформировать список добавляемых файлов, например, когда предварительно выбрал файлы, которые необходимо поместить в информационную базу;
● передать в метод маску поиска файлов, например, когда требуется поместить в информационную базу все файлы определенного вида,например, все картинки;
● передать в метод предварительно подготовленный объект ДиалогВыбораФайла в режиме открытия файлов.
После окончания работы метод может вернуть список реально добавленных файлов.

// СписокФайлов – реквизит формы типа СписокЗначений,
// содержащий список добавляемых файлов
МассивФайлов = Новый Массив;
Для каждого ЭлементСписка Из СписокФайлов Цикл
МассивФайлов.Добавить(Новый ОписаниеПередаваемогоФайла(ЭлементСписка, ));
КонецЦикла;
ПомещенныеФайлы = Новый Массив;
Результат = ПоместитьФайлы(МассивФайлов, ПомещенныеФайлы, , Ложь, УникальныйИдентификатор);

Примечание 1. Для использования метода ПоместитьФайлы() в веб-клиенте требуется подключение расширения работы с файлами .
Примечание 2. Объем данных, перемещаемых между клиентом и сервером, за один вызов метода ПоместитьФайлы(), не должен превышать 4 Gb (в сериализованном виде).

Помещение данных во временное хранилище

Метод ПоместитьВоВременноеХранилище() схож с методом ПоместитьФайл(), за исключением того, что данные для записи во временное хранилище
представляются не в виде пути в файловой системе, а в виде значения. Точно так же, если не указан существующий адрес во временном хранилище, создается новый адрес. Адрес возвращается как результат функции. Так же как и для файлов, размещенные данные обязательно принадлежат какой-либо форме и автоматически удаляются после ее удаления.
Примечание. Объем данных, перемещаемых между клиентом и сервером, за один вызов метода ПоместитьВоВременноеХранилище(), не должен превышать 4 Gb (в сериализованном виде).
Внимание! При помещении во временное хранилище фактическая сериализация значения не выполняется. Помещается ссылка на значение, которая хранится в кеше в течение 20 минут. По истечении этого периода значение сериализуется, записывается на диск (в хранилище сеансовых данных) и удаляется из кеша.

Получение данных из временного хранилища

При записи объекта в информационную базу может понадобиться извлечь данные из временного хранилища и поместить их, например, в реквизит объекта информационной базы. Для этого существует специальный метод – ПолучитьИзВременногоХранилища(). Этот метод извлекает данные из временного хранилища и возвращает их в качестве результата выполнения. Для получения данных необходимо указать адрес во временном
хранилище. Этот адрес возвращают методы помещения данных во временное хранилище в случае их успешного выполнения (см. предыдущие разделы).
Внимание! При получении на сервере значения из временного хранилища следует учитывать то, что оно получается по ссылке. В действительности, ссылка эта указывает на значение, которое хранится в кеше. В течение 20 минут, с момента помещения в хранилище или же с момента последнего обращения, значение сохранится в кеше, а затем записывается на диск и из кеша удаляется. При следующем обращении значение загружается с диска и снова помещается в кеш.
После десериализации и восстановления значения из временного хранилища ссылки не восстанавливаются. Значение в кеше восстанавливается с диска. Но после сериализации/десериализации восстановить ссылки на другие объекты внутри значения невозможно.

Удаление данных из временного хранилища

После того как данные сохранены в реквизите объекта информационной базы, данные во временном хранилище можно удалить. Для этого есть метод
УдалитьИзВременногоХранилища(), который производит удаление. Метод принимает в параметре адрес во временном хранилище.

Проверка адреса на принадлежность временному хранилищу

Адрес может указывать как на временное хранилище, так и на реквизит в информационной базе. Для проверки его типа существует метод
ЭтоАдресВременногоХранилища().  Он проверяет, что переданный адрес является адресом, указывающим на хранилище. Возвращает Истина, если адрес указывает на временное хранилище.

Получение адреса реквизита

После того как данные помещены в реквизит объекта информационной базы, может потребоваться получить доступ к ним с помощью файловых методов.
Но прежде чем получить данные, например из реквизита, необходимо получить адрес этого реквизита. Для этого существует метод ПолучитьНавигационнуюСсылку().

Он может вернуть адрес значения в информационной базе по исходным параметрам. Для этого необходимо передать ключ объекта (это может быть
как ссылка на объект, так и ключ записи регистра сведений) и имя реквизита. Если нужно получить адрес значения, хранимого в реквизите
табличной части, то к имени реквизита в параметре, задающем имя реквизита, необходимо добавить имя табличной части и точку «.». Например: Товары.Изображение

Получение файла из информационной базы

Получение одного файла

Метод ПолучитьФайл() получает файл из информационной базы и сохраняет его в локальную файловую систему пользователя. Первый параметр определяет адрес файла в реквизите объекта информационной базы или во временном хранилище файлов. Сохранение не произойдет, если у пользователя, от имени которого выполняется операция, отсутствует право Просмотр на реквизит объекта информационной базы. Второй параметр определяет место сохранения получаемого файла. В неинтерактивном режиме необходимо указать путь. В интерактивном режиме параметр является
опциональным.
По умолчанию метод исполняется в интерактивном режиме. Это значит, что будет сформировано диалоговое окно, в котором можно указать действие с полученным файлом: запустить его или сохранить в указанное пользователем место файловой системы. Если выбран интерактивный режим, а параметр Имя файла не указан, то операция открытия файла недоступна. Метод возвращает значение типа Булево. Ложь означает, что пользователь выбрал отмену операции в диалоговом окне сохранения файлов в интерактивном режиме.

Получение набора файлов

Метод ПолучитьФайлы() позволяет получить и сохранить в локальной файловой системе пользователя несколько файлов, хранящихся в информационной базе. В качестве параметра передается список выгружаемых файлов.

// СписокФайлов – список значений, содержащий ссылки на элементы
// справочника, в котором расположены выгружаемые файлы
// Представлением списка значений является имя выгружаемого файла
МассивФайлов = Новый Массив;
Для каждого ЭлементСписка Из СписокФайлов Цикл
Файл = Новый Файл(Строка(ЭлементСписка.Значение));
ПолучаемыйФайл = Новый ОписаниеПередаваемогоФайла;
ПолучаемыйФайл.Имя = ЭлементСписка.Представление;
ПолучаемыйФайл.Хранение = ПолучитьНавигационнуюСсылку(ЭлементСписка.Значение, “Данные”);
МассивФайлов.Добавить(ПолучаемыйФайл);
КонецЦикла;
ПолученныеФайлы = Новый Массив;
Результат = ПолучитьФайлы(МассивФайлов, ПолученныеФайлы, ПутьВыгружаемыхФайлов, Ложь);
Если НЕ Результат Тогда
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = “Ошибка получения файлов!”;
Сообщение.Сообщить();
КонецЕсли;

После окончания работы метод может вернуть список реально выгруженных файлов с указанием полного имени каждого сохраненного файла.
ПРИМЕЧАНИЕ. Для использования метода ПолучитьФайлы() в веб-клиенте требуется подключение расширения работы с файлами . В случае если свойство Имя объекта ОписаниеПередаваемогоФайла содержит абсолютный путь к файлу, файл будет сохранен по этому пути, без учета параметра РасположениеФайлов.
В качестве параметра РасположениеФайлов может выступать или путь в локальной файловой системе, или объект ДиалогВыбораФайлов в режиме выбора каталога или сохранения файлов. Если в качестве значения параметра РасположениеФайлов указан объект ДиалогВыбораФайлов в режиме
сохранения файлов, то:

● диалог будет вызываться для каждого передаваемого файла, кроме тех файлов, для которых свойство Имя объекта ОписаниеПередаваемогоФайла содержит абсолютный путь;
● в качестве начального имени файла в диалоге будет использоваться значение свойства Имя объекта ОписаниеПередаваемогоФайла;
● если для какого-либо файла будет выбран отказ от сохранения, то свойство Имя объекта ОписаниеПереданногоФайла будет содержать пустую строку;
● метод ПолучитьФайлы() вернет значение Истина, если хотя бы один файл получен успешно;
● следует учитывать, что собственно получение файлов выполняется после того, как пользователь ответит на вопросы по указанию имени и пути
всех получаемых файлов;
● если у пользователя, от имени которого выполняется метод ПолучитьФайлы(), отсутствует право Просмотр хотя бы на один реквизит объекта информационной базы, откуда выполняется получение файлов – неудачей завершится вся операция.
Пример:

ПередаваемыеФайлы = Новый Массив;
Описание = Новый ОписаниеПередаваемогоФайла(“Описание”, АдресФайла);
ПередаваемыеФайлы.Добавить(Описание);
ВыборФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
ВыборФайла.Заголовок = “Сохранение архива”;
ВыборФайла.Расширение = “zip”;
ВыборФайла.Фильтр = “Архив(*.zip)|*.zip|Все файлы|*.*”;
ВыборФайла.ИндексФильтра = 0;
ПолучитьФайлы(ПередаваемыеФайлы, , ВыборФайла, Ложь);

Если выбран интерактивный режим выбора каталога сохранения файлов, то веб-клиент будет дополнительно запрашивать разрешение на сохранение файлов, указанных с абсолютными путями. В случае неинтерактивного сохранения (путь к каталогу указан в соответствующем параметре) запрос будет выполнен для всего списка сохраняемых файлов.

Пример использования файловых методов

// Получение в интерактивном режиме файла с диска
// и помещение его во временное хранилище.
&НаКлиенте
Процедура ВыбратьФайлСДискаИЗаписать()
Перем ВыбранноеИмя;
Перем АдресВременногоХранилища;
НовыйОбъект = Объект.Ссылка.Пустая();
Если ПоместитьФайл(АдресВременногоХранилища, “”, ВыбранноеИмя, Истина) Тогда
Объект.ИмяФайла = ВыбранноеИмя;
ПоместитьФайлОбъекта(АдресВременногоХранилища);
КонецЕсли;
КонецПроцедуры
// Копирование файла из временного хранилища в реквизит
// справочника, запись объекта, удаление файла из временного
// хранилища.
&НаСервере
Процедура ПоместитьФайлОбъекта(АдресВременногоХранилища)
ЭлементСправочника = РеквизитФормыВЗначение(“Объект”);
ДвоичныеДанные = ПолучитьИзВременногоХранилища(АдресВременногоХранилища);
ЭлементСправочника.ДанныеФайла = Новый ХранилищеЗначения(ДвоичныеДанные, Новый СжатиеДанных());
Файл = Новый Файл(ЭлементСправочника.ИмяФайла);
ЭлементСправочника.ИмяФайла = Файл.Имя;
ЭлементСправочника.Записать();
Модифицированность = Ложь;
УдалитьИзВременногоХранилища(АдресВременногоХранилища);
ЗначениеВРеквизитФормы(ЭлементСправочника, “Объект”);
КонецПроцедуры
// Считывание файла из реквизита и сохранение его
// на локальном диске в интерактивном режиме.
&НаКлиенте
Процедура ПрочитатьФайлИСохранитьНаДиск()
Адрес = ПолучитьНавигационнуюСсылку(Объект.Ссылка,”ДанныеФайла”);
ПолучитьФайл(Адрес, Объект.ИмяФайла, Истина);
КонецПроцедуры

Разрешение на выполнение группы операций с файлами

При выполнении некоторых операций в веб-клиенте может потребоваться получить разрешение на несколько операций по работе с файлами.
Например, необходимо выполнить получение документа из информационной базы и затем открыть сохраненный документ с помощью ассоциированного приложения.
Для выполнения этой операции потребуется отвечать на вопрос о сохранении документа и на вопрос о необходимости запуска. Если операций будет больше, вопросов пользователю также станет больше.
Для уменьшения количества вопросов можно воспользоваться методом ЗапроситьРазрешениеПользователя(). При использовании этого метода
пользователю отображается список всех операций, которые планируется выполнить, и предлагается разрешить выполнение группы операций. Если пользователь разрешил выполнение, то запрошенные операции будут выполняться без дополнительных запросов пользователю. Если разрешение не предоставлено, операции будут выполняться в обычном режиме: один запрос на одну операцию.
ПРИМЕЧАНИЕ. Для использования метода ЗапроситьРазрешениеПользователя() в веб-клиенте требуется подключить расширение работы с файлами .
Рассмотрим пример использования метода:

Если ПодключитьРасширениеРаботыСФайлами() Тогда
Ссылка = ПолучитьНавигационнуюСсылку(Объект.Ссылка, “ДанныеФайла”);
// Формирование описания передаваемых файлов (в данном случае файл один)
ПередаваемыеФайлы = Новый Массив;
Описание = Новый ОписаниеПередаваемогоФайла(Объект.ИмяФайла, Ссылка);
ПередаваемыеФайлы.Добавить(Описание);
// Готовим объект для получения информации о полученных файлах
ПереданныеФайлы = Новый Массив;

// Определяем прочие параметры методов
КаталогСохранения = “c:\temp”;
Интерактивно = Ложь;
ИмяПереданногоФайла = КаталогСохранения + “\” + Объект.ИмяФайла;
// Готовим описание методов для получения разрешений
Методы = Новый Массив;
Методы.Добавить(Новый Массив);
Методы[0].Добавить(“ПолучитьФайлы”);
Методы[0].Добавить(ПередаваемыеФайлы);
Методы[0].Добавить(ПереданныеФайлы);
Методы[0].Добавить(КаталогСохранения);
Методы[0].Добавить(Интерактивно);
Методы.Добавить(Новый Массив);
Методы[1].Добавить(“ЗапуститьПриложение”);
Методы[1].Добавить(ИмяПереданногоФайла);
Если Не ЗапроситьРазрешениеПользователя(Методы) Тогда
Предупреждение(“Пользователь отказал в разрешении.”);
Возврат;
КонецЕсли;
ПолучитьФайлы(ПередаваемыеФайлы, ПереданныеФайлы, КаталогСохранения, Интерактивно);
ЗапуститьПриложение(ИмяПереданногоФайла);
Иначе
Предупреждение(“Выполнение не поддерживается. Не установлено расширение работы с файлами.”);
КонецЕсли;

Следует отметить несколько особенностей применения метода ЗапроситьРазрешениеПользователя().

1.  Разрешение запрашивается только для следующих методов:

ПолучитьФайлы()/НачатьПолучениеФайлов(),
● ПоместитьФайлы()/НачатьПомещениеФайлов(),
● НайтиФайлы()/НачатьПоискФайлов(),
● КопироватьФайл()/НачатьКопированиеФайла(),
● ПереместитьФайл()/НачатьПеремещениеФайла(),
● УдалитьФайлы()/НачатьУдалениеФайлов(),
● СоздатьКаталог()/НачатьСозданиеКаталога(),
● ЗапуститьПриложение()/НачатьЗапускПриложения().

2. Разрешение запрашивается для конкретного набора параметров метода. Если при реальном исполнении метода работы с файлами значения параметров будут отличаться от тех, для которых получено разрешение, это разрешение не будет действовать и пользователь получит отдельный запрос на подтверждение выполнения операции.

3. Если необходимо выполнить две (или более) одинаковые операции с файлами (даже с одинаковым набором параметров), следует указать соответствующее количество элементов в массиве параметров метода ЗапроситьРазрешениеПользователя(). Например, если необходимо дважды получить из информационной базы один и тот же файл и поместить его в фиксированное место файловой системы, следует запросить разрешение
на две операции.

4.  Если запрашивается разрешение на операцию, при выполнении которой выполняется интерактивная операция (например, функции ПолучитьФайлы() в качестве параметра передается объект ДиалогВыбораФайла), то такая операция исключается из запроса.

Полученные разрешения сохраняются либо до выполнения разрешенного вызова, либо до окончания исполнения встроенного языка.
ПРИМЕЧАНИЕ. В толстом и тонком клиентах ЗапроситьРазрешениеПользователя() метод всегда возвращает значение Истина, без взаимодействия с пользователем.

Работа с временным хранилищем в фоновом задании

В механизме работы с временным хранилищем есть возможность передать данные из фонового задания в сеанс, инициировавший фоновое задание.
Для такой передачи следует в родительском сеансе поместить во временное хранилище пустое значение (с помощью метода ПоместитьВоВременноеХранилище()), указав какой-либо идентификатор создаваемого временного хранилища (параметр Адрес). Затем полученный адрес передать в фоновое задание через параметры фонового задания. Далее, если в фоновом задании этот адрес использовать в качестве значения параметра Адрес метода ПоместитьВоВРеменноеХранилище(), то результат будет скопирован в сеанс, из которого было запущено фоновое задание.
Данные, помещенные во временное хранилище в фоновом задании, не будут доступны из родительского сеанса до момента завершения фонового задания.

Поддержка адресов в поле картинки

Элемент формы Поле вида Поле картинки поддерживает отображение картинки, заданной адресом значения (которое может быть картинкой или двоичными данными) во временном хранилище или в базе данных.
Для этого в свойстве Данные элемента формы необходимо задать реквизит строкового типа. Значение этого реквизита и будет интерпретироваться как адрес картинки.

// Пример 1
// Привязка поля картинки к адресу картинки во временном
// хранилище. АдресКартинки – реквизит формы строкового типа
ПоместитьФайл(АдресКартинки, ИсходноеИмя, ВыбранноеИмя, Истина, УникальныйИдентификатор);
// Пример 2
// Получение адреса картинки из реквизита объекта
// информационной базы
ФайлКартинки = Объект.ФайлКартинки;
Если Не ФайлКартинки.Пустая() Тогда
АдресКартинки = ПолучитьНавигационнуюСсылку(ФайлКартинки, “ДанныеФайла”);
Иначе
АдресКартинки = “”;
Конецесли;

Доступ к стандартным каталогам

При использовании системы требуется некоторое место в файловой системе, где можно хранить различные файловые данные, которые с одной стороны являются временными, а с другой – должны храниться достаточно длительное время. К таким файлам можно отнести черновики для систем управления документооборотом, внешние компоненты, работающие на стороне клиентского компьютера и т. д.
Для хранения таких файлов предназначен специальный каталог, который привязан к конкретному пользователю конкретной информационной базы.
Один и тот же пользователь, работающий с двумя информационными базами, будет иметь доступ к двум разным каталогам хранения данных пользователя. Местоположение данного каталога определяется с помощью метода РабочийКаталогДанныхПользователя(). Если каталог отсутствует, то он создается при первом обращении к нему. Если создание каталога невозможно – система вызывает исключение.
ПРИМЕЧАНИЕ. Метод РабочийКаталогДанныхПользователя()не доступен на стороне сервера.
В операционной системе имеется специальный каталог, выделенный для постоянного хранения данных пользователя. Это могут быть какие-то
отчеты, печатные формы документов и т. д. В этот каталог помещаются данные, которые в дальнейшем могут быть отправлены внешним
потребителям. Для доступа к этому каталогу предназначен метод КаталогДокументов(). Физическое расположение каталога зависит от операционной
системы, где исполняется приложение и приведено в синтакс-помощнике.

Добавить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *